globalA1Degree -- computes a global A1-Brouwer degree of a list of n polynomials in n variables over a field k

Synopsis

• Usage:

  globalA1Degree(L)

• Inputs:
  • L, a list, of polynomials $f = (f_1, \ldots, f_n)$ in the polynomial ring $k[x_1,\ldots,x_n]$ over a field $k$
• Outputs:
  • a Grothendieck Witt Class, the class $\text{deg}^{\mathbb{A}^1}(f)$ in the Grothendieck-Witt ring $\text{GW}(k)$

Description

Given an endomorphism of affine space $f=(f_1,\dots ,f_n) \colon \mathbb{A}^n_k \to \mathbb{A}^n_k$ with isolated zeros, we may compute its $\mathbb{A}^1$-Brouwer degree valued in the Grothendieck-Witt ring $\text{GW}(k)$.

The $\mathbb{A}^1$-Brouwer degree first defined by Morel [M12] is an algebro-geometric enrichment of the classical topological Brouwer degree. Using the tools of motivic homotopy theory, one may associate to an endomorphism of affine space the isomorphism class of a symmetric bilinear form whose invariants encode geometric data about how the morphism transforms space.

Such an association appears in the work of Eisenbud-Levine [EL77] and Khimshiashvili [K77], wherein the authors develop a symmetric bilinear form whose signature computes the local degree of a smooth map of real manifolds in the case where the Jacobian may vanish on an affine chart. This was proven to agree with Morel's $\mathbb{A}^1$-Brouwer degree in work of Kass and Wickelgren [KW19]. A similar production of a symmetric bilinear form is given by work of Scheja and Storch [SS76], which develops a symmetric bilinear form attached to a complete intersection. This was also shown to align with the $\mathbb{A}^1$-Brouwer degree in [BW23].

Following recent work of B. McKean and Pauli [BMP23], the $\mathbb{A}^1$-Brouwer degree can be computed as a multivariate Bezoutian bilinear form. The algorithms for producing such a form are developed here.

i1 : QQ[x];

i2 : f = {x^2+1};

i3 : globalA1Degree(f)

o3 = GrothendieckWittClass{cache => CacheTable{}}
                           matrix => | 0 1 |
                                     | 1 0 |

o3 : GrothendieckWittClass

The previous example produces a rank two form with signature zero. This corresponds to the fact that the degree of the complex map $\mathbb{C}\to\mathbb{C},\ z\mapsto z^2$ has degree two, while the associated real map $\mathbb{R}\to\mathbb{R},\ x\mapsto x^2$ has global degree zero.

Following [M21] we may think about the $\mathbb{A}^1$-Brouwer degree $\text{deg}^{\mathbb{A}^1}(f)$ as a quadratically enriched intersection multiplicity of the hyperplanes $V(f_1)\cap \cdots \cap V(f_n).$ As a toy example, consider the curve $y=x(x-1)(x+1)$ intersecting the $x$-axis.

i4 : QQ[x,y];

i5 : f = {x^3 - x^2 - y, y};

i6 : globalA1Degree(f)

o6 = GrothendieckWittClass{cache => CacheTable{}}
                           matrix => | 0  -1 1 |
                                     | -1 1  0 |
                                     | 1  0  0 |

o6 : GrothendieckWittClass

The rank of this form is three, as cubics over the complex numbers have three roots counted with multiplicity. This form has signature one, which indicates that when the cubic intersects the $x$-axis, when the three points of intersection are counted with a sign corresponding to a right hand rule, the sum equals one.

The global $\mathbb{A}^1$-Brouwer degree can be computed as a sum over the local degrees at the points in the zero locus of the morphism. In the previous example, we see that $V(f)$ consists of three points on the affine line. We can compute local degrees at all of these and verify that the local degrees sum to the global degree:

i7 : QQ[x,y];

i8 : f = {x^3 - x^2 - y, y};

i9 : point1 = ideal{x-1, y};

o9 : Ideal of QQ[x..y]

i10 : point2 = ideal{x, y};

o10 : Ideal of QQ[x..y]

i11 : globalA1Degree(f);

i12 : localA1Degree(f,point1);

i13 : localA1Degree(f,point2);

i14 : gwIsomorphic(globalA1Degree(f), gwAdd(localA1Degree(f,point1), localA1Degree(f,point2)));

Citations:

• [BW23] T. Bachmann, K. Wickelgren, Euler classes: six-functors formalism, dualities, integrality and linear subspaces of complete intersections, J. Inst. Math. Jussieu, 2023.
• [EL77] D. Eisenbud, H. Levine, An algebraic formula for the degree of a C^infinity map germ, Annals of Mathematics, 1977.
• [K77] G. Khimshiashvili, The local degree of a smooth mapping, Sakharth. SSR Mcn. Akad. Moambe, 1977.
• [KW19] J. Kass, K. Wickelgren, The class of Eisenbud-Khimshashvili-Levine is the local A1-Brouwer degree, Duke Math J., 2019.
• [M21] S. McKean, An arithmetic enrichment of Bezout's Theorem, Math. Ann., 2021.
• [M12] F. Morel, A1-Algebraic topology over a field, Springer Lecture Notes in Mathematics, 2012.
• [BMP23] T. Brazelton, S. McKean, S. Pauli, Bezoutians and the A1-Degree, Algebra & Number Theory, 2023.
• [SS76] S. Scheja, S. Storch, Uber Spurfunktionen bei vollstandigen Durchschnitten, J. Reine Angew. Math., 1975.

See also

• localA1Degree -- computes a local A1-Brouwer degree of a list of n polynomials in n variables over a field k at a prime ideal in the zero locus
• sumDecomposition -- produces a simplified diagonal representative of a Grothendieck Witt class
• sumDecompositionString -- produces a simplified diagonal representative of a Grothendieck Witt class