Macaulay2 » Documentation
Packages » CellularResolutions :: hullComplex
next | previous | forward | backward | up | index | toc

hullComplex -- gives the hull complex of a monomial ideal

Synopsis

Description

Given a monomial ideal $I$, this function returns the hull complex of that ideal. If an rational number $t$ is provided, this will set the base used in the exponents used to construct the polytope as described in ``Combinatorial Commutative Algebra.'' The resulting complex is only a resolution for $t\gg 0$. In particular $t > (n+1)!$ is sufficient where $n$ is the number of variables in the ring. If t is not provided, $(n+1)!+1$ will be used.

The example given below can be found as Example 4.23 in Miller-Sturmfels' ``Combinatorial Commutative Algebra.'' In this example, the resolution supported on the hull complex is minimal, but this is not always the case. We also see that for $t=3/2$ the resulting complex is no longer a resolution.

i1 : S = QQ[x,y,z];
 
i2 : I = monomialIdeal (x^2*z, x*y*z, y^2*z, x^3*y^5, x^4*y^4, x^5*y^3);

o2 : MonomialIdeal of S
 
i3 : H = hullComplex I

o3 = H

o3 : CellComplex
 
i4 : chainComplex H

      1      6      7      2
o4 = S  <-- S  <-- S  <-- S
                           
     -1     0      1      2

o4 : ChainComplex
 
i5 : cells(1,H)/cellLabel

         2    4 4    5 3    5 4   3 5    4 5   2
o5 = {x*y z, x y z, x y z, x y , x y z, x y , x y*z}

o5 : List
 
i6 : cells(2,H)/cellLabel

       4 5    5 4
o6 = {x y z, x y z}

o6 : List
 
i7 : isMinimal H

o7 = true
 
i8 : H2 = hullComplex (3/2,I)

o8 = H2

o8 : CellComplex
 
i9 : prune HH chainComplex H2

o9 = -1 : cokernel | y2z xyz x2z x3y5 x4y4 x5y3 |

      0 : cokernel {4} | x 0 0 |
                   {9} | 0 z x |                 

      1 : 0                                      

      2 : 0                                      

o9 : GradedModule

See also

Ways to use hullComplex :

For the programmer

The object hullComplex is a method function.