deCone(CentralArrangement,RingElement) -- produce an affine arrangement from a central one

Synopsis

Function: deCone
Usage:

deCone(A, x)

deCone(A, i)
Inputs:
- A, a central hyperplane arrangement,
- x, a ring element, a hyperplane of $A$ or the index of a hyperplane of $A$
Outputs:
- a hyperplane arrangement, the decone of $A$ over $x$

Description

The decone of a central arrangement $A$ at a hyperplane $H=H_i$ or $H=\ker x$ is the affine arrangement obtained from $A$ by first deleting the hyperplane $H$ then intersecting the remaining hyperplanes with the (affine) hyperplane $\{x=1\}$. In particular, if $R$ is the coordinate ring of $A$, then the coordinate ring of its decone over $x$ is $R/(x-1)$.

The decone of a central arrangement at $H$ can also be constructed by first projectivizing $A$, then removing the image of $H$, and identifying the complement of $H$ with affine space.

i1 : A = arrangement "X3"

o1 = {x , x , x , x  + x , x  + x , x  + x }
       1   2   3   1    2   1    3   2    3

o1 : Hyperplane Arrangement

i2 : dA = deCone(A,2)

o2 = {x , x , x  + x , x  + 1, x  + 1}
       1   2   1    2   1       2

o2 : Hyperplane Arrangement

i3 : factor poincare A

                        2
o3 = (1 + T)(1 + 5T + 7T )

o3 : Expression of class Product

i4 : poincare dA

                2
o4 = 1 + 5T + 7T

o4 : ZZ[T]

The coordinate ring of $dA$ is $\mathbb{Q}[x_1,x_2,x_3]/(x_3-1)$.

i5 : ring dA

     QQ[x ..x ]
         1   3
o5 = ----------
       x  - 1
        3

o5 : QuotientRing

Use prune to get something whose coordinate ring is a polynomial ring.

i6 : dA' = prune dA

o6 = {x , x , x  + x , x  + 1, x  + 1}
       1   2   1    2   1       2

o6 : Hyperplane Arrangement

i7 : ring dA'

o7 = QQ[x ..x ]
         1   2

o7 : PolynomialRing

Ways to use this method: