NormalToricVariety ^** ZZ -- make the Cartesian power of a normal toric variety

Synopsis

Operator: ^**
Usage:

X ^** i
Inputs:
- X, a normal toric variety,
- i, an integer, that is positive
Outputs:
- a normal toric variety, the i-ary Cartesian product of X with itself

Description

The $i$-ary Cartesian product of the variety $X$, defined over the ground field $k$, is the $i$-ary fiber product of $X$ with itself over $k$. For a normal toric variety, the fan of the $i$-ary Cartesian product is given by the $i$-ary Cartesian product of the cones.

i1 : PP2 = toricProjectiveSpace 2;

i2 : X = PP2 ^** 4;

i3 : fromWDivToCl X

o3 = | 1 1 1 0 0 0 0 0 0 0 0 0 |
     | 0 0 0 1 1 1 0 0 0 0 0 0 |
     | 0 0 0 0 0 0 1 1 1 0 0 0 |
     | 0 0 0 0 0 0 0 0 0 1 1 1 |

              4       12
o3 : Matrix ZZ  <-- ZZ

The factors are cached and can be accessed with components.

i4 : factors = components X

o4 = {PP2, PP2, PP2, PP2}

o4 : List

i5 : assert (# factors === 4)

i6 : assert all (4, i -> factors#i === PP2)

i7 : FF2 = hirzebruchSurface (2);

i8 : Y = FF2 ^** 3;

i9 : fromWDivToCl Y

o9 = | 1 -2 1 0 0 0  0 0 0 0  0 0 |
     | 0 1  0 1 0 0  0 0 0 0  0 0 |
     | 0 0  0 0 1 -2 1 0 0 0  0 0 |
     | 0 0  0 0 0 1  0 1 0 0  0 0 |
     | 0 0  0 0 0 0  0 0 1 -2 1 0 |
     | 0 0  0 0 0 0  0 0 0 1  0 1 |

              6       12
o9 : Matrix ZZ  <-- ZZ

i10 : X' = PP2 ** PP2;

i11 : X'' = PP2 ^** 2;

i12 : assert (rays X' == rays X'' and  max X' == max X'')

Ways to use this method:

NormalToricVariety ^** ZZ -- make the Cartesian power of a normal toric variety

NormalToricVariety ^** ZZ -- make the Cartesian power of a normal toric variety

Synopsis

Description

See also

Ways to use this method: