NormalToricVariety _ ZZ -- make an irreducible torus-invariant divisor

Synopsis

Operator: _
Usage:

X_i
Inputs:
- X, a normal toric variety,
- i, an integer, indexing a ray in the fan associated to X
Outputs:
- a toric divisor, namely the irreducible torus-invariant divisor associated to the i-th ray in the fan of X

Description

The irreducible torus-invariant divisors on a normal toric variety correspond to the rays in the associated fan. In this package, the rays are ordered and indexed by the nonnegative integers. Given a normal toric variety and nonnegative integer, this method returns the corresponding irreducible torus-invariant divisor. The most convenient way to make a general torus-invariant Weil divisor is to simply write the appropriate linear combination of these torus-invariant Weil divisors.

There are three irreducible torus-invariant divisors on the projective plane.

i1 : PP2 = toricProjectiveSpace 2;

i2 : PP2_0

o2 = PP2
        0

o2 : ToricDivisor on PP2

i3 : PP2_1

o3 = PP2
        1

o3 : ToricDivisor on PP2

i4 : PP2_2

o4 = PP2
        2

o4 : ToricDivisor on PP2

i5 : assert (- PP2_0 - PP2_1 - PP2_2 === toricDivisor PP2)

A torus-invariant Weil divisor is irreducible if and only if its support has a single element.

i6 : X = normalToricVariety (id_(ZZ^3) | -id_(ZZ^3));

i7 : X_0

o7 = X
      0

o7 : ToricDivisor on X

i8 : support X_0

o8 = {0}

o8 : List

i9 : assert( # support X_0 === 1)

i10 : K = toricDivisor X

o10 = - X  - X  - X  - X  - X  - X  - X  - X
         0    1    2    3    4    5    6    7

o10 : ToricDivisor on X

i11 : support K

o11 = {0, 1, 2, 3, 4, 5, 6, 7}

o11 : List

Ways to use this method:

NormalToricVariety _ ZZ -- make an irreducible torus-invariant divisor

NormalToricVariety _ ZZ -- make an irreducible torus-invariant divisor

Synopsis

Description

See also

Ways to use this method: