affineSpace(ZZ) -- make an affine space as a normal toric variety

Synopsis

Function: affineSpace
Usage:

affineSpace d
Inputs:
- d, an integer, a positive integer
Optional inputs:
- CoefficientRing => a ring, default value QQ, that specifies the coefficient ring of the total coordinate ring
- Variable => a symbol, default value x, that specifies the base name for the indexed variables in the total coordinate ring
Outputs:
- a normal toric variety, that is affine $d$-space

Description

Affine $d$-space is a smooth normal toric variety. The rays are generated by the standard basis $e_1, e_2, \dots, e_d$ of $\ZZ^d$, and the maximal cone in the fan correspond to the $d$-element subsets of $\{ 0, 1, \dots, d-1 \}$.

The examples illustrate the affine line and affine $3$-space.

i1 : AA1 = affineSpace 1;

i2 : rays AA1

o2 = {{1}}

o2 : List

i3 : max AA1

o3 = {{0}}

o3 : List

i4 : dim AA1

o4 = 1

i5 : assert (isWellDefined AA1 and not isComplete AA1 and isSmooth AA1)

i6 : AA3 = affineSpace (3, CoefficientRing => ZZ/32003, Variable => y);

i7 : rays AA3

o7 = {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}

o7 : List

i8 : max AA3

o8 = {{0, 1, 2}}

o8 : List

i9 : dim AA3

o9 = 3

i10 : ring AA3

        ZZ
o10 = -----[y ..y ]
      32003  0   2

o10 : PolynomialRing

i11 : assert (isWellDefined AA3 and not isComplete AA3 and isSmooth AA3)

Ways to use this method: