isVeryAmple(ToricDivisor) -- whether a torus-invariant Weil divisor is very ample

Synopsis

Function: isVeryAmple
Usage:

isVeryAmple D
Inputs:
- D, a toric divisor,
Outputs:
- a Boolean value, that is true if the divisor is very ample

Description

A Cartier divisor is very ample when it is basepoint free and the map arising from its complete linear series is a closed embedding. On a normal toric variety, the following are equivalent:

the divisor is a very ample divisor;
for every vertex of the associated lattice polytope associated to the divisor, the corresponding semigroup is saturated in the group characters.

On a smooth normal toric variety every ample divisor is very ample.

i1 : PP3 = toricProjectiveSpace 3;

i2 : assert isAmple PP3_0

i3 : assert isVeryAmple PP3_0

i4 : FF2 = hirzebruchSurface 2;

i5 : assert isAmple (FF2_2 + FF2_3)

i6 : assert isVeryAmple (FF2_2 + FF2_3)

A Cartier divisor is ample when some positive integer multiple is very ample. On a normal toric variety of dimension $d$, the $(d-1)$ multiple of any ample divisor is always very ample.

i7 : X = normalToricVariety matrix {{0,1,0,0,1},{0,0,1,0,1},{0,0,0,1,1},{0,0,0,0,3}};

i8 : assert (dim X === 4)

i9 : D = 3*X_0

o9 = 3*X
        0

o9 : ToricDivisor on X

i10 : assert isAmple D

i11 : assert not isVeryAmple D

i12 : assert not isVeryAmple (2*D)

i13 : assert isVeryAmple (3*D)

Ways to use this method: