polyoToric -- Toric ideal of a polyomino

Synopsis

Usage:

polyoToric(Q,H)
Inputs:
- Q, a list of lists whose elements are the lists of diagonal corners of each cell.
- H, a list of the lower left corners of the holes.
Outputs:
- A toric ideal attached to the polyomino encoded by Q.

Description

Let $\mathcal{P}$ be a polyomino. A finite collection $\mathcal{H}$ of cells not in $\mathcal{P}$ is called a hole of $\mathcal{P}$, if any two cells in $\mathcal{H}$ are connected by a path of cells in $\mathcal{H}$ and $\mathcal{H}$ is maximal with respect to the set inclusion. Consider the following total order on $V(\mathcal{P})$: $a=(i,j)>b=(k, l)$, if $i > k$, or $i = k$ and $j > l$. If $\mathcal{H}$ is a hole of $\mathcal{P}$, then we call lower left corner $e$ of $\mathcal{H}$ the minimum, with respect to <, of the vertices of $\mathcal{H}$. Let $\mathcal{H}_1,\dots, \mathcal{H}_r$ be the holes of $\mathcal{P}$ and $e_k = (i_k, j_k)$ be the lower left corner of $\mathcal{H}_k$. For $k \in K =[r]$, we define the following subset $F_k = \{(i, j) \in V (\mathcal{P}) : i \leq i_k, j \leq j_k\}$. Denote by $\{V_i\}_{i\in I}$ the set of all the maximal vertical edge intervals of $\mathcal{P}$, and by $\{H_j \}_{j\in J}$ the set of all the maximal horizontal edge intervals of $\mathcal{P}$. Let $\{v_i\}_{i\in I}$, $\{H_j\}_{j\in J}$ , and $\{w_k\}_{k∈K}$ be three sets of variables. We consider the map $$\alpha : V (\mathcal{P}) \rightarrow K[{h_i, v_j , w_k } : i \in I, j \in J, k \in K]$$ $$a \rightarrow \prod_{a\in H_i \cap V_j} h_iv_j \prod_{a\in F_k} w_k$$ The toric ring $T_{\mathcal{P}}$ associated to $\mathcal{P}$ is defined as $T_{\mathcal{P}} = K[\alpha(a):a \in V (\mathcal{P})]$. The homomorphism $\psi : S \rightarrow T_{\mathcal{P}}$ with $x_a \rightarrow \alpha(a)$ is surjective and the toric ideal $J_{\mathcal{P}}$ is the kernel of $\psi$.
Note that the homomorphism $\psi$ defined before is a natural generalization of that given in [QSS2017] for simple polyominoes.

Given the polyomino encoded by Q and the list H of the lower left corners of each hole of the polyomino, the function polyoToric returns the toric ideal $J_{\mathcal{P}}$ defined before.

Literature

[QSS2017] Simple polyominoes are prime (A.A. Qureshi, T. Shibuta, A. Shikama, 2017, J. Commut. Algebra 9(3), 413-422).
[MRR2020] Primality of multiply connected polyominoes (C. Mascia, G. Rinaldo, F. Romeo, 2020, Illinois J. Math. 64(3), 291-304).
[CNU2022] Primality of weakly connected collections of cells and weakly closed path polyominoes (C. Cisto, F. Navarra, R. Utano, 2022, Illinois J. Math. 66(4), 545-563).

Examples

i1 : Q={{{1, 1}, {2, 2}}, {{2, 1}, {3, 2}}, {{3, 1}, {4, 2}}, {{3, 2}, {4, 3}}, {{3, 3}, {4, 4}}, {{2, 3}, {3, 4}}, {{1, 3}, {2, 4}}, {{1, 2}, {2, 3}}};

i2 : J=polyoToric(Q,{{2,2}})

o2 = ideal (- x   x    + x   x   , - x   x    + x   x   , - x   x    +
               2,2 1,1    2,1 1,2     3,2 1,1    3,1 1,2     4,2 1,1  
     ------------------------------------------------------------------------
     x   x   , - x   x    + x   x   , - x   x    + x   x   , - x   x    +
      4,1 1,2     2,3 1,1    2,1 1,3     2,3 1,2    2,2 1,3     2,4 1,1  
     ------------------------------------------------------------------------
     x   x   , - x   x    + x   x   , - x   x    + x   x   , - x   x    +
      2,1 1,4     2,4 1,2    2,2 1,4     2,4 1,3    2,3 1,4     3,4 1,3  
     ------------------------------------------------------------------------
     x   x   , - x   x    + x   x   , - x   x    + x   x   , - x   x    +
      3,3 1,4     4,4 1,3    4,3 1,4     3,2 2,1    3,1 2,2     4,2 2,1  
     ------------------------------------------------------------------------
     x   x   , - x   x    + x   x   , - x   x    + x   x   , - x   x    +
      4,1 2,2     3,4 2,3    3,3 2,4     4,4 2,3    4,3 2,4     4,2 3,1  
     ------------------------------------------------------------------------
     x   x   , - x   x    + x   x   , - x   x    + x   x   , - x   x    +
      4,1 3,2     4,3 3,1    4,1 3,3     4,3 3,2    4,2 3,3     4,4 3,1  
     ------------------------------------------------------------------------
     x   x   , - x   x    + x   x   , - x   x    + x   x   )
      4,1 3,4     4,4 3,2    4,2 3,4     4,4 3,3    4,3 3,4

o2 : Ideal of QQ[x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   ]
                  4,4   4,3   4,2   4,1   3,4   3,3   3,2   3,1   2,4   2,3   2,2   2,1   1,4   1,3   1,2   1,1

i3 : Q={{{3, 1}, {4, 2}}, {{4, 1}, {5, 2}}, {{5, 1}, {6, 2}}, {{5, 2}, {6, 3}}, {{5, 3}, {6, 4}}, {{5, 4}, {6, 5}}, {{5, 5}, {6, 6}}, {{4, 5}, {5, 6}}, {{3, 2}, {4, 3}}, {{3, 3}, {4, 4}}, {{2, 3}, {3, 4}}, {{1, 3}, {2, 4}}, {{1, 4}, {2, 5}}, {{1, 5}, {2, 6}}, {{2, 5}, {3, 6}}, {{3, 5}, {4, 6}}};

i4 : I=polyoIdeal(Q);

o4 : Ideal of QQ[x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   ]
                  6,6   6,5   6,4   6,3   6,2   6,1   5,6   5,5   5,4   5,3   5,2   5,1   4,6   4,5   4,4   4,3   4,2   4,1   3,6   3,5   3,4   3,3   3,2   3,1   2,6   2,5   2,4   2,3   1,6   1,5   1,4   1,3

i5 : J=polyoToric(Q,{{2,4}});

o5 : Ideal of QQ[x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   ]
                  6,6   6,5   6,4   6,3   6,2   6,1   5,6   5,5   5,4   5,3   5,2   5,1   4,6   4,5   4,4   4,3   4,2   4,1   3,6   3,5   3,4   3,3   3,2   3,1   2,6   2,5   2,4   2,3   1,6   1,5   1,4   1,3

i6 : R=ring I

o6 = R

o6 : PolynomialRing

i7 : J=substitute(J,R);

o7 : Ideal of R

i8 : J==I

o8 = true

Morevover, if $\mathcal{P}$ is a simple polyomino, that is it has not any hole, then the function polyoToric works setting H={} and it returns the polyomino ideal of $\mathcal{P}$ in according to [QSS2017].

i9 : Q={{{2, 1}, {3, 2}}, {{3, 1}, {4, 2}}, {{2, 2}, {3, 3}}, {{1, 2}, {2, 3}}, {{3, 2}, {4, 3}}, {{2, 3}, {3, 4}}};

i10 : I=polyoIdeal(Q);

o10 : Ideal of QQ[x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   ]
                   4,3   4,2   4,1   3,4   3,3   3,2   3,1   2,4   2,3   2,2   2,1   1,3   1,2

i11 : J=polyoToric(Q,{});

o11 : Ideal of QQ[x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   ]
                   4,3   4,2   4,1   3,4   3,3   3,2   3,1   2,4   2,3   2,2   2,1   1,3   1,2

i12 : R=ring I

o12 = R

o12 : PolynomialRing

i13 : J=substitute(J,R);

o13 : Ideal of R

i14 : J==I

o14 = true

In general, the function polyoToric works also for weakly connected collection of cells. If $\mathcal{P}$ is the non-simple collections of cells in Figure (A) of the Remark 3.4 in [CNU2022], we know that the inner 2-minor ideal of $\mathcal{P}$ is not prime.

i15 : Q={{{2, 1}, {3, 2}}, {{3, 2}, {4, 3}}, {{1, 2}, {2, 3}}, {{2, 3}, {3, 4}}};

i16 : I=polyoIdeal(Q);

o16 : Ideal of QQ[x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   ]
                   4,3   4,2   3,4   3,3   3,2   3,1   2,4   2,3   2,2   2,1   1,3   1,2

i17 : J=polyoToric(Q,{{2,2}});

o17 : Ideal of QQ[x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   , x   ]
                   4,3   4,2   3,4   3,3   3,2   3,1   2,4   2,3   2,2   2,1   1,3   1,2

i18 : R=ring I

o18 = R

o18 : PolynomialRing

i19 : J=substitute(J,R);

o19 : Ideal of R

i20 : J==I

o20 = false

i21 : select(first entries gens J,f->first degree f>=3)

o21 = {x   x   x    - x   x   x   , x   x   x    - x   x   x   , -
        3,2 2,1 1,3    3,1 2,3 1,2   4,3 3,2 2,4    4,2 3,4 2,3   
      -----------------------------------------------------------------------
      x   x   x   x    + x   x   x   x   }
       4,3 3,1 2,4 1,2    4,2 3,4 2,1 1,3

o21 : List

Ways to use polyoToric :

polyoToric(List,List)

For the programmer

The object polyoToric is a method function.