continuousProbabilityDistribution -- construct a continuous probability distribution

Synopsis

Usage:

continuousProbabilityDistribution f
Inputs:
- f, a function, the probability density function of X, to be used by density.
Optional inputs:
- DistributionFunction => a function, default value null, the cumulative distribution function of X, to be used by probability. If null, then obtained by numerically integrating f.
- QuantileFunction => a function, default value null, the quantile function of X, to be used by quantile. If null, then obtained by using the bisection method.
- RandomGeneration => a function, default value null, a function for generating random samples from X, to be used by random(ProbabilityDistribution). If null, then obtained using inverse transform sampling.
- Support => a sequence, default value (0,infinity), containing the lower and upper bounds, respectively, of the support of X.
- Description => a string, default value "a continuous probability distribution", describing the probability distribution.
Outputs:
- X, a continuous probability distribution,

Description

To construct a continuous probability distribution, provide the probability density function and, if different than the default of \([0, \infty\]), the support.

i1 : X = continuousProbabilityDistribution(x -> 2 * x, Support => (0, 1))

o1 = a continuous probability distribution

o1 : ContinuousProbabilityDistribution

i2 : density_X 0.75

o2 = 1.5

o2 : RR (of precision 53)

Values outside the support are automatically sent to 0.

i3 : density_X 2

o3 = 0

The cumulative distribution, quantile, and random generation functions are set to defaults based on the probability density function.

i4 : probability_X 0.75

o4 = .5625

o4 : RR (of precision 53)

i5 : quantile_X 0.5625

o5 = .75

o5 : RR (of precision 53)

i6 : random X

o6 = .944834293327094

o6 : RR (of precision 53)

However, if possible, it is good to provide these directly to improve performance. A description may also be provided.

i7 : X = continuousProbabilityDistribution(x -> 2 * x, Support => (0, 1),
         DistributionFunction => x -> x^2,
         QuantileFunction => p -> sqrt p,
         Description => "triangular distribution")

o7 = triangular distribution

o7 : ContinuousProbabilityDistribution

Caveat

When defining a probability density function, the user must be careful that it satisfies the definition, i.e., it must be nonnegative and it must integrate to 1 on its support.

Ways to use continuousProbabilityDistribution :

continuousProbabilityDistribution(Function)

For the programmer

The object continuousProbabilityDistribution is a method function with options.