discreteProbabilityDistribution -- construct a discrete probability distribution

Synopsis

Usage:

discreteProbabilityDistribution f
Inputs:
- f, a function, the probability mass function of X, to be used by density.
Optional inputs:
- DistributionFunction => a function, default value null, the cumulative distribution function of X, to be used by probability. If null, then obtained by adding values of f.
- QuantileFunction => a function, default value null, the quantile function of X, to be used by quantile. If null, then obtained by adding values of f.
- RandomGeneration => a function, default value null, a function for generating random samples from X, to be used by random(ProbabilityDistribution). If null, then obtained using inverse transform sampling.
- Support => a sequence, default value (0,infinity), containing the lower and upper bounds, respectively, of the support of X. Elements of the support are assumed to be integers.
- Description => a string, default value "a discrete probability distribution", describing the probability distribution.
Outputs:
- X, a discrete probability distribution,

Description

To construct a discrete probability distribution, provide the probability mass function and, if different than the default of \([0, \infty\]), the support.

i1 : X = discreteProbabilityDistribution(x -> 1/6, Support => (1, 6))

o1 = a discrete probability distribution

o1 : DiscreteProbabilityDistribution

i2 : density_X 3

     1
o2 = -
     6

o2 : QQ

Non-integers and values outside the support are automatically sent to 0.

i3 : density_X 3.5

o3 = 0

i4 : density_X 7

o4 = 0

The cumulative distribution, quantile, and random generation functions are set to defaults based on the probability mass function.

i5 : probability_X 3

     1
o5 = -
     2

o5 : QQ

i6 : quantile_X 0.2

o6 = 2

i7 : random X

o7 = 6

However, if possible, it is good to provide these directly to improve performance. A description may also be provided.

i8 : X = discreteProbabilityDistribution(x -> 1/6, Support => (1, 6),
         DistributionFunction => x -> x / 6,
         QuantileFunction => p -> 6 * p,
         Description => "six-sided die")

o8 = six-sided die

o8 : DiscreteProbabilityDistribution

Caveat

When defining a probability mass function, the user must be careful that it satisfies the definition, i.e., it must be nonnegative and its values must sum to 1 on its support.

Ways to use discreteProbabilityDistribution :

discreteProbabilityDistribution(Function)

For the programmer

The object discreteProbabilityDistribution is a method function with options.