isSameMap -- whether two rational maps to between projective varieties are really the same

Synopsis

Usage:

b = isSameMap(f1, f2)

phi == psi

b = isSameMap(phi, psi)
Inputs:
- f1, a ring map, a map of rings corresponding to a rational map between projective varieties
- f2, a ring map, a map of rings corresponding to a rational map between projective varieties
- phi, an instance of the type RationalMapping, a map between projective varieties
- psi, an instance of the type RationalMapping, a rational map between projective varieties
Outputs:
- b, a Boolean value, true if the rational maps are the same, false otherwise.

Checks whether two rational maps between projective varieties are really the same (that is, agree on a dense open set).

i1 : R=QQ[x,y,z];

i2 : S=QQ[a,b,c];

i3 : f1=map(R, S, {y*z,x*z,x*y});

o3 : RingMap R <-- S

i4 : f2=map(R, S, {x*y*z,x^2*z,x^2*y});

o4 : RingMap R <-- S

i5 : isSameMap(f1,f2)

o5 = true

The Cremona transformation is not the identity, but its square is.

i6 : R = ZZ/7[x,y,z]

o6 = R

o6 : PolynomialRing

i7 : phi = rationalMapping(R, R, {y*z,x*z,x*y})

o7 = Proj R - - - > Proj R   {y*z, x*z, x*y}

o7 : RationalMapping

i8 : ident = rationalMapping(R, R, {x,y,z})

o8 = Proj R - - - > Proj R   {x, y, z}

o8 : RationalMapping

i9 : phi == ident

o9 = false

i10 : phi^2 == ident

o10 = true