barycentricSubdivision(SimplicialComplex,Ring) -- create the barycentric subdivision of a simplicial complex

Synopsis

Function: barycentricSubdivision
Usage:

barycentricSubdivision(D,R)
Inputs:
- Delta, an abstract simplicial complex,
- R, a ring, the ambient ring for the barycentric subdivision of $D$
Outputs:
- an abstract simplicial complex, the barycentric subdivision of $D$

Description

If $\Delta$ is an abstract simplicial complex, the barycentric subdivision of $\Delta$ is the abstract simplicial complex whose ground set (vertices) is the set of faces of $D$ and whose faces correspond to sequences $\{(F_0, F_1, \ldots, F_k)\}$ where $F_i$ is an $i$-dimensional face containing $F_{i-1}$. In order to understand how the data of the barycentric subdivision is organized, we work through a simple example.

i1 : R = QQ[x_0..x_2];

i2 : S = QQ[y_0..y_6];

i3 : Δ = simplexComplex(2, R)

o3 = simplicialComplex | x_0x_1x_2 |

o3 : SimplicialComplex

i4 : Γ = barycentricSubdivision(Δ, S)

o4 = simplicialComplex | y_2y_5y_6 y_1y_5y_6 y_2y_4y_6 y_0y_4y_6 y_1y_3y_6 y_0y_3y_6 |

o4 : SimplicialComplex

i5 : ΓFacets = facets Γ

o5 = {y y y , y y y , y y y , y y y , y y y , y y y }
       2 5 6   1 5 6   2 4 6   0 4 6   1 3 6   0 3 6

o5 : List

To make sense of the facets of the barycentric subdivision, we order the faces of $\Delta$ as follows.

i6 : ΔFaces = flatten for i to 1 + dim Δ list faces(i, Δ)

o6 = {x , x , x , x x , x x , x x , x x x }
       0   1   2   0 1   0 2   1 2   0 1 2

o6 : List

The indices of the variables appearing in each monomial (or facet) $F$ in the facets of $\Gamma$ determines a sequence of monomials (faces) in $\Delta$.

i7 : netList for F in ΓFacets list F => ΔFaces_(indices F)

     +----------------------------+
o7 = |y y y  => {x , x x , x x x }|
     | 2 5 6      2   1 2   0 1 2 |
     +----------------------------+
     |y y y  => {x , x x , x x x }|
     | 1 5 6      1   1 2   0 1 2 |
     +----------------------------+
     |y y y  => {x , x x , x x x }|
     | 2 4 6      2   0 2   0 1 2 |
     +----------------------------+
     |y y y  => {x , x x , x x x }|
     | 0 4 6      0   0 2   0 1 2 |
     +----------------------------+
     |y y y  => {x , x x , x x x }|
     | 1 3 6      1   0 1   0 1 2 |
     +----------------------------+
     |y y y  => {x , x x , x x x }|
     | 0 3 6      0   0 1   0 1 2 |
     +----------------------------+

Ways to use this method: