Description
The vertices of the barycentric subdivision of $D$ correspond to faces of $D$. For every face $F$ in $D$, $\operatorname{barycentricSubdivision} (f,R,S)$ maps the vertex corresponding to $F$ in the barycentric subdivision of $D$ to the vertex corresponding to $f(F)$ in the barycentric subdivision of $E$. We work out these correspondences, and the resulting simplicial map between barycentric subdivisions in the example below.
i1 : T = ZZ/2[x_0,x_1,x_2];
|
i2 : Δ = simplicialComplex{T_1*T_2}
o2 = simplicialComplex | x_1x_2 |
o2 : SimplicialComplex
|
i3 : Γ = simplicialComplex{T_0*T_1}
o3 = simplicialComplex | x_0x_1 |
o3 : SimplicialComplex
|
i4 : f = map(Γ, Δ, reverse gens T)
o4 = | x_2 x_1 x_0 |
o4 : SimplicialMap simplicialComplex | x_0x_1 | <--- simplicialComplex | x_1x_2 |
|
The barycentric subdivisions of $D$, $E$, and $f$ are:
i5 : R = ZZ/2[y_0..y_2];
|
i6 : S = ZZ/2[z_0..z_2];
|
i7 : BΔ = barycentricSubdivision(Δ, R)
o7 = simplicialComplex | y_1y_2 y_0y_2 |
o7 : SimplicialComplex
|
i8 : BΓ = barycentricSubdivision(Γ, S)
o8 = simplicialComplex | z_1z_2 z_0z_2 |
o8 : SimplicialComplex
|
i9 : Bf = barycentricSubdivision(f, S, R)
o9 = | z_1 z_0 z_2 |
o9 : SimplicialMap simplicialComplex | z_1z_2 z_0z_2 | <--- simplicialComplex | y_1y_2 y_0y_2 |
|
In order to understand the data for $Bf$, we first look at the correspondence between the faces of $\Delta$, $\Gamma$, and the vertices of $B\Delta$, $B\Gamma$, respectively.
i10 : ΔFaces = flatten for i to dim Δ + 1 list faces(i, Δ)
o10 = {x , x , x x }
1 2 1 2
o10 : List
|
i11 : ΓFaces = flatten for i to dim Γ + 1 list faces(i, Γ)
o11 = {x , x , x x }
0 1 0 1
o11 : List
|
i12 : netList transpose {for y in vertices BΔ list y => ΔFaces_(index y),
for z in vertices BΓ list z => ΓFaces_(index z)}
+----------+----------+
o12 = |y => x |z => x |
| 0 1 | 0 0 |
+----------+----------+
|y => x |z => x |
| 1 2 | 1 1 |
+----------+----------+
|y => x x |z => x x |
| 2 1 2| 2 0 1|
+----------+----------+
|
These correspondences, together the images of each face of $D$ under $f$, will completely determine the map $Bf$.
i13 : netList transpose {for F in ΔFaces list F => (map f)(F),
for v in vertices BΔ list v => (map Bf)(v) }
+------------+--------+
o13 = |x => x |y => z |
| 1 1 | 0 1|
+------------+--------+
|x => x |y => z |
| 2 0 | 1 0|
+------------+--------+
|x x => x x |y => z |
| 1 2 0 1| 2 2|
+------------+--------+
|
i14 : Bf
o14 = | z_1 z_0 z_2 |
o14 : SimplicialMap simplicialComplex | z_1z_2 z_0z_2 | <--- simplicialComplex | y_1y_2 y_0y_2 |
|