Ext^ZZ(Matrix,Module) -- map between Ext modules

Synopsis

Scripted functor: Ext
Usage:

Ext^i(f,N)
Inputs:
- i, an integer
- f, a matrix, M1 --> M2
- N, a module
Outputs:
- a matrix, the map $Ext^i(M2,N) \rightarrow{} Ext^i(M1,N)$

Description

If N is an ideal or ring, it is regarded as a module in the evident way.

i1 : R = ZZ/32003[a..d];

i2 : I = monomialCurveIdeal(R,{1,3,4})

                        3      2     2    2    3    2
o2 = ideal (b*c - a*d, c  - b*d , a*c  - b d, b  - a c)

o2 : Ideal of R

i3 : M1 = R^1/I

o3 = cokernel | bc-ad c3-bd2 ac2-b2d b3-a2c |

                            1
o3 : R-module, quotient of R

i4 : M2 = R^1/ideal(I_0,I_1)

o4 = cokernel | bc-ad c3-bd2 |

                            1
o4 : R-module, quotient of R

i5 : f = inducedMap(M1,M2)

o5 = | 1 |

o5 : Matrix M1 <-- M2

i6 : Ext^1(f,R)

o6 = 0

o6 : Matrix 0 <-- 0

i7 : g = Ext^2(f,R)

o7 = {-5} | -d2 -cd c2 |

o7 : Matrix

i8 : source g == Ext^2(M1,R)

o8 = true

i9 : target g == Ext^2(M2,R)

o9 = true

i10 : Ext^3(f,R)

o10 = 0

o10 : Matrix

Ways to use this method: