isFano(NormalToricVariety) -- whether a normal toric variety is Fano

Synopsis

Function: isFano
Usage:

isFano X
Inputs:
- X, a normal toric variety,
Outputs:
- a Boolean value, that is true if the normal toric variety is Fano

Description

A normal toric variety is Fano if its anticanonical divisor, namely the sum of all the torus-invariant irreducible divisors, is ample. This is equivalent to saying that the polyhedron associated to the anticanonical divisor is a reflexive polytope.

Projective space is Fano.

i1 : PP3 = toricProjectiveSpace 3;

i2 : assert isFano PP3

i3 : K = toricDivisor PP3

o3 = - PP3  - PP3  - PP3  - PP3
          0      1      2      3

o3 : ToricDivisor on PP3

i4 : isAmple (-K)

o4 = true

i5 : assert all (5, d -> isFano toricProjectiveSpace (d+1))

There are eighteen smooth Fano toric threefolds.

i6 : assert all (18, i -> (X := smoothFanoToricVariety (3,i); isSmooth X and isFano X))

There are also many singular Fano toric varieties.

i7 : X = normalToricVariety matrix {{1,0,-1},{0,1,-1}};

i8 : assert (not isSmooth X and isFano X)

i9 : Y = normalToricVariety matrix {{1,1,-1,-1},{0,1,1,-1}};

i10 : assert (not isSmooth Y and isFano Y)

i11 : Z = normalToricVariety (id_(ZZ^3) | -id_(ZZ^3));

i12 : assert (not isSmooth Z and isFano Z)

To avoid duplicate computations, the attribute is cached in the normal toric variety.

Ways to use this method: